Sans avoir lu la page d'Introduction, vous risquez de vous exposer à quelques déconvenues...
POUR .EFFAS :NC
FCURS :.CURS REPETE :NC [TAPE CAR 32]
FCURS :.CURS
FIN
POUR .SAISI :L
DONNE ".CURS CURS
DONNE ".SAISIE LL
SI VIDE? :.SAISIE [.EFFAS COMPTE :.SAISIE RENDS .SAISI :L STOP]
DONNE ".SAISIE PREM :.SAISIE
SI NON NOMBRE? :.SAISIE [.EFFAS COMPTE :.SAISIE RENDS .SAISI :L STOP]
SI NON MEMBRE? :.SAISIE :L [.EFFAS COMPTE :.SAISIE RENDS .SAISI :L STOP]
[RENDS :.SAISIE]
FIN
POUR NIVEAU
FCT 4 TAPE [VITESSE: 1 $(lent$) a 12 $(rapide$) ?]
DONNE "V .SAISI [1 2 3 4 5 6 7 8 9 10 11 12]
FCT 15
FIN
POUR PALMARES
SI PLG? :S :RECORD [DONNE "RECORD :S DONNE "NRECORD :NOM AFRECORD]
FIN
POUR YCOR
RENDS DER POS
FIN
POUR XCOR
RENDS PREM POS
FIN
POUR AFRECORD
SORTIE 6 FTCAR [2 2] FCURS [12 1] FCT 1 FCFT 3
TAPE [RECORD :] FCT 4
TAPE PH PH :NRECORD :RECORD POINTS :RECORD
FTCAR [1 1] FCT 1 FCFT 0 SORTIE 1
FIN
POUR POINTS :N
SI :N < 2 [RENDS "POINT][RENDS "POINTS]
FIN
POUR NOM
FCT 4 FCURS [10 2] TAPE [TON PRENOM ?]
DONNE "NOM LL FCT 1
FIN
POUR AFNOM
SORTIE 6 FTCAR [2 2] FCURS [2 21] FCFT 0 FCT 15
TAPE :NOM FCT 9 TAPE PH MOT CAR 32 :S POINTS :S
FTCAR [1 1] SORTIE 1
FIN
POUR AFNIVEAU
SORTIE 6 FTCAR [2 2] FCURS [55 21] FCFT 0 FCT 9
TAPE PH "VITESSE MOT :V CAR 32
FTCAR [1 1] SORTIE 1
FIN
POUR BLUFF
REPETE HASARD 10 [DONNE "BLUFF HASARD 20]
PRET
FIN
POUR TEST
SI EGAL? 32 ASCII LISCAR [FCURS [0 3] EC " FTCAR [1 1] FCT 1 AFNOM
STOP] [BLUFF]
FIN
POUR PRET
FTCAR [2 2] FCURS [13 3] FCT 2 TAPE [TAPE LA BARRE QUAND TU ES PRET !]
SI TOUCHE? [TEST] [BLUFF]
FIN
POUR PERDU
VT FTCAR [2 1] FCT 2 FCURS [8 1] EC [AIE! C'EST FINI POUR TOI...] FCT 1
REPETE 3 [JOUE "SISILALASOSOFAFAMIMIREREDODO]
PALMARES
FIN
POUR ENCORE?
FCT 2 FCURS [8 3] TAPE [UNE AUTRE PARTIE ?]
DONNE "L LL
SI VIDE? :L [RENDS ENCORE? STOP]
FCT 15
SI EGAL? "O PREM :L [RENDS VRAI]
RENDS FAUX
FIN
POUR TOUCHEMURS?
SI OU XCOR > 270 XCOR < -270 [RENDS VRAI]
SI OU YCOR > 140 YCOR < -140 [RENDS VRAI]
RENDS FAUX
FIN
POUR DEPLACEMENT
ACTION :V
FIN
POUR ACTION :V
SI PLP? :V 0 [STOP]
AV :V AFNIVEAU
SI TOUCHEMURS? [PERDU STOP]
SI TOUCHESALADE? [MANGE PLANTESALADE RETOUR]
SI TOUCHE? [ACTION TESTER LISCAR][ACTION :V]
FIN
POUR TESTER :T
SI EGAL? :T 19712 [TD 90 RENDS :V]
SI EGAL? :T 19200 [TG 90 RENDS :V]
SI ET EGAL? :T 20480 PLG? :V 0 [DONNE "V DIFF :V 1 RENDS :V]
SI ET EGAL? :T 18432 PLP? :V 12 [DONNE "V SOMME :V 1 RENDS :V]
SI EGAL? :T "F [CLOS FTCAR [1 1] DONNE "V -1 RENDS :V]
FIN
POUR DEPART
LC ORIGINE MT FCC 6
FIN
POUR RECT :LA :LO
REPETE 2 [AV :LA TD 90 AV :LO TD 90]
FIN
POUR MURS
FCC 12 CT LC RE 140 TG 90 AV 270 TD 90
BC RECT 280 540
FIN
POUR HASARDANS :L
RENDS SOMME PREM :L HASARD ( SOMME 1 DIFF DER :L PREM :L )
FIN
POUR RETOUR
LC FPOS :ICI FCAP :CAAP
MT FCC 6
FIN
POUR MANGE
BC FCC CF DONNE "ICI POS DONNE "CAAP CAP
DONNE "S SOMME :S PROD :V 1
VE MURS AFRECORD AFNOM AFNIVEAU RETOUR
JOUE "DOREMIFASO LC
FIN
POUR TOUCHESALADE?
RENDS EGAL? CPOINT POS 10
FIN
POUR PLANTESALADE
RECYCLE DONNE "XS DIFF (10 * HASARDANS [-26 26]) 5
DONNE "YS DIFF (10 * HASARDANS [-13 13]) 5
CT LC FPOS LISTE :XS :YS
BC FCC 10 SALADE FCC 6
FIN
POUR SALADE
FCAP 0 REPETE 4 [AV 11 TD 90] LC TD 45 AV 2 BC REMPLIS RE 2 TG 45
FIN
POUR JEU
TE FTCAR [2 2] FCT 10 EC [LES SALADES] EC []
FTCAR [1 2] FCT 4 TAPE [Bonjour! Quel est ton prenom ?]
DONNE "NOM LL FCT 10 EC []
EC [Guide la tortue jusqu'a la salade en utilisant les deux fleches ]
EC [DROITE et GAUCHE, pour la tourner.]
EC [Les fleches HAUT et BAS accelerent ou ralentissent la vitesse.]
EC [] EC PH PH [Bonne chance] :NOM [!]
SI NON NOM? "RECORD [DONNE "RECORD 0 DONNE "NRECORD "]
DUREE 1 EC [] NIVEAU
ME 5 VE FCFG 0 VT
AFRECORD
DONNE "S 0
MURS AFNIVEAU DEPART PRET
CT PLANTESALADE DEPART AFREGLE
DEPLACEMENT
SI ENCORE? [JEU] [FTCAR [1 1] ]
FIN
POUR AFREGLE
FCT 15
FCURS [19 0] EC [FLECHE DROITE .. Tourne a droite de 90ø]
FCURS [19 1] EC [FLECHE GAUCHE .. Tourne a gauche de 90ø]
FCURS [19 2] EC [FLECHE HAUT ................. Accelerer]
FCURS [19 3] EC [FLECHE BAS ................... Ralentir]
FCURS [15 4] TAPE [1 Salade mangee = 1 Point MULTIPLIE par la vitesse]
FIN
© Olivier Schmidt-Chevalier - nov., dec. 2003 |